Просматривая группы новостей SQL Server, время от времени я вижу запрос на сценарий, который может выполнять поиск во всех столбцах всех таблиц dj всей базе данных MS SQL по определенному ключевому слову. Я никогда серьезно не относился к таким постам. Но недавно один из моих сетевых администраторов устранял проблему с Microsoft Operations Manager (MOM). MOM использует SQL Server для хранения всей информации о компьютере, предупреждениях и производительности. Он сузил проблему до чего-то конкретного и нуждался в сценарии, который мог бы искать во всех таблицах MOM определенную строку. В то время у меня не было под рукой такого скрипта, поэтому пришлось искать вручную.
Именно тогда я действительно почувствовал потребность в таком сценарии и придумал хранимую процедуру SearchForAll. Он принимает строку поиска в качестве входного параметра, выполняет поиск во всех столбцах char, varchar, nchar, nvarchar всех таблиц (только таблицы, созданные пользователем, системные таблицы исключены), принадлежащих всем пользователям в текущей базе данных. Не стесняйтесь расширять эту процедуру для поиска других типов данных.
Выходные данные этой хранимой процедуры содержат два столбца:
- Имя таблицы и имя столбца, в котором была найдена строка поиска.
- Фактическое содержание / значение столбца (отображаются только первые 3630 символов)
ПРЕДУПРЕЖДЕНИЕ! Перед тем, как приступить к выполнению этой процедуры, сделайте небольшое предостережение. Хотя эта процедура выполняется довольно быстро в небольших базах данных, на большую базу данных со слишком большим количеством символьных столбцов и огромным количеством строк может потребоваться несколько часов.
Итак, если вы пытаетесь запустить его в большой базе данных, будьте готовы подождать (я использовал подсказку о блокировке NOLOCK, чтобы уменьшить любую блокировку). Функцию полнотекстового поиска эффективно использовать для поиска по произвольному тексту, но это не имеет смысла для этого типа специальных требований.
Создайте эту процедуру в требуемой базе данных, и затем запускаете ее в нужный момент при помощи кода:
--Поиск во всех столбцах всех таблиц в базе данных Pubs по ключевому слову "Компьютер"
EXEC SearchForAll 'Компьютер'
GOВот полный код хранимой процедуры, ищущий ключевую фразу во всех таблицах базы:
CREATE PROC SearchForAll
(
@SearchStr nvarchar(100)
)
AS
BEGIN
-- Copyright © 2002 Narayana Vyas Kondreddi. All rights reserved.
-- Purpose: To search all columns of all tables for a given search string
-- Written by: Narayana Vyas Kondreddi
-- Site: http://vyaskn.tripod.com
-- Tested on: SQL Server 7.0 and SQL Server 2000
-- Date modified: 28th July 2002 22:50 GMT
CREATE TABLE #Results (ColumnName nvarchar(370), ColumnValue nvarchar(3630))
SET NOCOUNT ON
DECLARE @TableName nvarchar(256), @ColumnName nvarchar(128), @SearchStr2 nvarchar(110)
SET @TableName = ''
SET @SearchStr2 = QUOTENAME('%' + @SearchStr + '%','''')
WHILE @TableName IS NOT NULL
BEGIN
SET @ColumnName = ''
SET @TableName =
(
SELECT MIN(QUOTENAME(TABLE_SCHEMA) + '.' + QUOTENAME(TABLE_NAME))
FROM INFORMATION_SCHEMA.TABLES
WHERE TABLE_TYPE = 'BASE TABLE'
AND QUOTENAME(TABLE_SCHEMA) + '.' + QUOTENAME(TABLE_NAME) > @TableName
AND OBJECTPROPERTY(
OBJECT_ID(
QUOTENAME(TABLE_SCHEMA) + '.' + QUOTENAME(TABLE_NAME)
), 'IsMSShipped'
) = 0
)
WHILE (@TableName IS NOT NULL) AND (@ColumnName IS NOT NULL)
BEGIN
SET @ColumnName =
(
SELECT MIN(QUOTENAME(COLUMN_NAME))
FROM INFORMATION_SCHEMA.COLUMNS
WHERE TABLE_SCHEMA = PARSENAME(@TableName, 2)
AND TABLE_NAME = PARSENAME(@TableName, 1)
AND DATA_TYPE IN ('char', 'varchar', 'nchar', 'nvarchar')
AND QUOTENAME(COLUMN_NAME) > @ColumnName
)
IF @ColumnName IS NOT NULL
BEGIN
INSERT INTO #Results
EXEC
(
'SELECT ''' + @TableName + '.' + @ColumnName + ''', LEFT(' + @ColumnName + ', 3630)
FROM ' + @TableName + ' (NOLOCK) ' +
' WHERE ' + @ColumnName + ' LIKE ' + @SearchStr2
)
END
END
END
SELECT ColumnName, ColumnValue FROM #Results
END
